Trinidev

package document
{
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.net.URLRequest;
	import flash.system.ApplicationDomain;
	import flash.system.LoaderContext;
	import flash.system.Security;
 
	/**
	 * ...
	 * @author Pascal Achard
	 */
	public class MainClass extends Sprite
	{
 
		private var _loader:Loader;
		private var _player:Object;
 
		public function MainClass():void
		{
			// On alligne le player.
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
			// On définit la sécu.
			Security.allowInsecureDomain("*");
			Security.allowDomain("*");
 
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
 
			// Send a trace
 
			// entry point
 
			var context:LoaderContext = new LoaderContext();
			//context.applicationDomain = ApplicationDomain.currentDomain;
			context.applicationDomain = new ApplicationDomain();
			context.checkPolicyFile = true;
 
			_loader = new Loader();
			_loader.contentLoaderInfo.addEventListener(Event.INIT, _onLoaderInit);
			_loader.load(new URLRequest("http://www.youtube.com/apiplayer?version=3"));
		}
 
		private function _onLoaderInit(e:Event):void
		{
			addChild(_loader);
			_loader.content.addEventListener("onReady", _onPlayerReady);
			_loader.content.addEventListener("onError", _onPlayerError);
			_loader.content.addEventListener("onStateChange", _onPlayerStateChange);
			_loader.content.addEventListener("onPlaybackQualityChange", _onVideoPlaybackQualityChange);
 
		}
 
		private function _onPlayerReady(e:Event):void
		{
			// Event.data contains the event parameter, which is the Player API ID
			trace("player ready:", Object(e).data);
 
			// Once this event has been dispatched by the player, we can use
			// cueVideoById, loadVideoById, cueVideoByUrl and loadVideoByUrl
			// to load a particular YouTube video.
			_player = _loader.content;
			_player.setSize(640, 408);
			_player.cueVideoById("CETo6PvEPE0");
		}
 
		private function _onPlayerError(e:Event):void
		{
			// Event.data contains the event parameter, which is the error code
			trace("player error:", Object(e).data);
		}
 
		private function _onPlayerStateChange(e:Event):void
		{
			// Event.data contains the event parameter, which is the new player state
			trace("player state:", Object(e).data);
		}
 
		private function _onVideoPlaybackQualityChange(e:Event):void
		{
			// Event.data contains the event parameter, which is the new video quality
			trace("video quality:", Object(e).data);
		}
 
	}
 
}